quickhit.pro 6.1 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217
  1. # Copyright (c) 2011 Nokia Corporation.
  2. QT += core gui declarative
  3. TARGET = quickhit
  4. TEMPLATE = app
  5. VERSION = 2.0.1
  6. INCLUDEPATH += ./ge_src/
  7. SOURCES += \
  8. src/gameengine.cpp \
  9. src/invsounds.cpp \
  10. src/main.cpp \
  11. src/mainwindow.cpp \
  12. src/myeventfilter.cpp \
  13. src/plugindata.cpp \
  14. ge_src/GEAudioBuffer.cpp \
  15. ge_src/GEAudioBufferPlayInstance.cpp \
  16. ge_src/GEAudioMixer.cpp \
  17. ge_src/GEAudioOut.cpp \
  18. ge_src/GEInterfaces.cpp
  19. HEADERS += \
  20. src/gameengine.h \
  21. src/invsounds.h \
  22. src/mainwindow.h \
  23. src/myeventfilter.h \
  24. src/plugindata.h \
  25. plugins/levelplugininterface.h \
  26. ge_src/GEAudioBuffer.h \
  27. ge_src/GEAudioBufferPlayInstance.h \
  28. ge_src/GEAudioMixer.h \
  29. ge_src/GEAudioOut.h \
  30. ge_src/GEInterfaces.h \
  31. ge_src/trace.h
  32. RESOURCES += rsc/resources.qrc
  33. OTHER_FILES += qml/*.qml
  34. # Uncomment/comment the following line to enable/disable debug prints of
  35. # Qt GameEnabler audio framework.
  36. #DEFINES += GE_DEBUG
  37. symbian {
  38. TARGET = QuickHit
  39. TARGET.UID3 = 0xe7ced714
  40. TARGET.EPOCSTACKSIZE = 0x14000
  41. TARGET.EPOCHEAPSIZE = 0x20000 0x5000000
  42. TARGET.CAPABILITY = \
  43. LocalServices \
  44. Location \
  45. NetworkServices \
  46. ReadUserData \
  47. WriteUserData \
  48. UserEnvironment
  49. QT += multimedia
  50. CONFIG += mobility
  51. MOBILITY = systeminfo
  52. RESOURCES += rsc/no_components.qrc
  53. LIBS += -lcone -leikcore -lavkon -lhwrmvibraclient
  54. ICON = icons/icon.svg
  55. # Add LevelOne.sis into QuickHit sis
  56. levelone.pkg_postrules.main = "IF NOT package(0xE07dfb66)"\
  57. "; Install levelone.sis only if not already installed"\
  58. "@\"levelone.sis\", (0xE07dfb66)" \
  59. "endif "
  60. DEPLOYMENT += levelone
  61. PRIVATEDIR = $$replace(TARGET.UID3, "^0x", "")
  62. # Enables In-App Purchase API
  63. #DEFINES += IA_PURCHASE
  64. contains(DEFINES, IA_PURCHASE) {
  65. message(In-App Purchase API enabled)
  66. QT += network script
  67. MOBILITY += serviceframework
  68. INCLUDEPATH += ./iap_src
  69. HEADERS += \
  70. iap_src/downloadmanager.h \
  71. iap_src/iapurchase.h \
  72. iap_src/product.h \
  73. iap_src/request.h
  74. SOURCES += \
  75. iap_src/downloadmanager.cpp \
  76. iap_src/iapurchase.cpp \
  77. iap_src/product.cpp
  78. LIBS += -liapclientapi
  79. iap_dependency.pkg_prerules = \
  80. "; Has dependency on IAP component" \
  81. "(0x200345C8), 0, 2, 6, {\"IAP\"}"
  82. DEPLOYMENT += iap_dependency
  83. iapVariantId.sources = ./iap/IAP_VARIANTID.txt
  84. iapVariantId.path = .
  85. DEPLOYMENT += iapVariantId
  86. # Enables test mode for IAP
  87. #DEFINES += IA_PURCHASE_TEST_MODE
  88. # For testing In-App Purchase without Nokia Store
  89. contains(DEFINES, IA_PURCHASE_TEST_MODE) {
  90. message(In-App Purchase API in TEST_MODE)
  91. addConfigFiles.sources = ./iap/TEST_MODE.txt
  92. addConfigFiles.path = .
  93. DEPLOYMENT += addConfigFiles
  94. }
  95. }
  96. !contains(SYMBIAN_VERSION, Symbian3) {
  97. # In Symbian 1 we do not have OpenGL available
  98. DEFINES += QT_NO_OPENGL
  99. }
  100. else {
  101. # Uncomment/comment the following line to enable/disable the Symbian
  102. # volume hack.
  103. #DEFINES += QTGAMEENABLER_USE_VOLUME_HACK
  104. }
  105. contains(DEFINES, QTGAMEENABLER_USE_VOLUME_HACK) {
  106. warning(Using Symbian volume hack!)
  107. INCLUDEPATH += /epoc32/include/mmf/common
  108. INCLUDEPATH += /epoc32/include/mmf/server
  109. LIBS += -lmmfdevsound
  110. }
  111. }
  112. unix:!symbian {
  113. CONFIG += mobility
  114. MOBILITY = systeminfo
  115. BINDIR = /opt/usr/bin
  116. DATADIR = /usr/share
  117. DEFINES += DATADIR=\\\"$$DATADIR\\\" \
  118. PKGDATADIR=\\\"$$PKGDATADIR\\\"
  119. target.path = $$BINDIR
  120. icon64.path = $$DATADIR/icons/hicolor/64x64/apps
  121. icon64.files += icons/$${TARGET}.png
  122. maemo5 {
  123. message(Maemo build)
  124. RESOURCES += rsc/no_components.qrc
  125. OTHER_FILES += qml/no_components.qml
  126. QT += opengl multimedia
  127. desktop.path = $$DATADIR/applications/hildon
  128. desktop.files += qtc_packaging/debian_fremantle/$${TARGET}.desktop
  129. }
  130. else{
  131. message(Harmattan build)
  132. DEFINES += Q_WS_MAEMO_6
  133. MOBILITY += multimedia
  134. RESOURCES += rsc/harmattan.qrc
  135. OTHER_FILES += qml/harmattan.qml
  136. desktop.path = $$DATADIR/applications/
  137. desktop.files += qtc_packaging/debian_harmattan/$${TARGET}.desktop
  138. # Classify the application as a game to support volume keys on Harmattan.
  139. gameclassify.files += qtc_packaging/debian_harmattan/$${TARGET}.conf
  140. gameclassify.path = /usr/share/policy/etc/syspart.conf.d
  141. INSTALLS += gameclassify
  142. }
  143. INSTALLS += \
  144. target \
  145. desktop \
  146. icon64
  147. }
  148. win32 {
  149. message(Windows)
  150. TARGET = QuickHit
  151. QT += multimedia
  152. RESOURCES += rsc/no_components.qrc
  153. # Copy level files into c:\\quickhitdata folder
  154. system(mkdir c:\\quickhitdata)
  155. system(mkdir c:\\quickhitdata\\levelone\\gfx)
  156. system(mkdir c:\\quickhitdata\\levelone\\sound)
  157. system(mkdir c:\\quickhitdata\\leveltwo\\gfx)
  158. system(mkdir c:\\quickhitdata\\leveltwo\\sound)
  159. system(copy plugins\\LevelOne\\Level.qml c:\\quickhitdata\\levelone)
  160. system(copy plugins\\LevelOne\\gfx\\*.* c:\\quickhitdata\\levelone\\gfx)
  161. system(copy plugins\\LevelOne\\sound\\*.* c:\\quickhitdata\\levelone\\sound)
  162. system(copy plugins\\LevelTwo\\qml\\Level.qml c:\\quickhitdata\\leveltwo)
  163. system(copy plugins\\LevelTwo\\qml\\Enemy.qml c:\\quickhitdata\\leveltwo)
  164. system(copy plugins\\LevelTwo\\qml\\Level.js c:\\quickhitdata\\leveltwo)
  165. system(copy plugins\\LevelTwo\\gfx\\*.* c:\\quickhitdata\\leveltwo\\gfx)
  166. system(copy plugins\\LevelTwo\\sound\\*.* c:\\quickhitdata\\leveltwo\\sound)
  167. }