gnumach4linux-libre/xen/configfrag.ac

dnl Configure fragment for the Xen platform.

dnl Copyright (C) 2007 Free Software Foundation, Inc.

dnl This program is free software; you can redistribute it and/or modify it
dnl under the terms of the GNU General Public License as published by the
dnl Free Software Foundation; either version 2, or (at your option) any later
dnl version.
dnl
dnl This program is distributed in the hope that it will be useful, but
dnl WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
dnl or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
dnl for more details.
dnl
dnl You should have received a copy of the GNU General Public License along
dnl with this program; if not, write to the Free Software Foundation, Inc.,
dnl 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA.

#
# Xen platform.
#

[if [ "$host_platform" = xen ]; then]
  AC_DEFINE([MACH_XEN], [], [build a MachXen kernel])
  AC_DEFINE([MACH_HYP], [], [be a hypervisor guest])
  AM_CONDITIONAL([PLATFORM_xen], [true])

dnl These are experimental

  AC_ARG_ENABLE([pseudo-phys],
    AS_HELP_STRING([--disable-pseudo-phys], [Pseudo physical pages support]))
  [if [ x"$enable_pseudo_phys" = xno ]; then]
    AM_CONDITIONAL([enable_pseudo_phys], [false])
  [else]
    AC_DEFINE([MACH_PSEUDO_PHYS], [], [Enable pseudo physical memory support])
    AM_CONDITIONAL([enable_pseudo_phys], [true])
  [fi]

  AC_ARG_ENABLE([pv-pagetables],
    AS_HELP_STRING([--disable-pv-pagetables], [Paravirtualized page tables support]))
  [if [ x"$enable_pv_pagetables" = xno ]; then]
    AM_CONDITIONAL([enable_pv_pagetables], [false])
  [else]
    AC_DEFINE([MACH_PV_PAGETABLES], [], [Enable paravirtualized page tables support])
    AM_CONDITIONAL([enable_pv_pagetables], [true])
  [fi]

  AC_ARG_ENABLE([pv-descriptors],
    AS_HELP_STRING([--disable-pv-descriptors], [Paravirtualized segment descriptors support]))
  [if [ x"$enable_pv_descriptors" = xno ]; then]
    AM_CONDITIONAL([enable_pv_descriptors], [false])
  [else]
    AC_DEFINE([MACH_PV_DESCRIPTORS], [], [Enable paravirtualized segment descriptors support])
    AM_CONDITIONAL([enable_pv_descriptors], [true])
  [fi]

  AC_ARG_ENABLE([ring1],
    AS_HELP_STRING([--disable-ring1], [ring1 kernel support]))
  [if [ x"$enable_ring1" = xno ]; then]
    AM_CONDITIONAL([enable_ring1], [false])
  [else]
    AC_DEFINE([MACH_RING1], [], [Enable ring1 kernel support])
    AM_CONDITIONAL([enable_ring1], [true])
  [fi]

[else]
  AM_CONDITIONAL([PLATFORM_xen], [false])
  AM_CONDITIONAL([enable_pseudo_phys], [false])
  AM_CONDITIONAL([enable_pv_pagetables], [false])
  AM_CONDITIONAL([enable_pv_descriptors], [false])
  AM_CONDITIONAL([enable_ring1], [false])
[fi]

dnl Local Variables:
dnl mode: autoconf
dnl End: