123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990 |
- # Maintainer: Martin Diehl <aur@martin-diehl.net>
- # Contributor: Samuel Williams <samuel.williams@oriontransfer.co.nz>
- pkgname=scotch
- pkgver=7.0.4
- pkgrel=1
- pkgdesc="Software package and libraries for graph, mesh and hypergraph partitioning, static mapping, and sparse matrix block ordering. This is the all-inclusive version (MPI/serial/esmumps)."
- url="https://gitlab.inria.fr/scotch/scotch"
- license=("custom:CeCILL-C")
- depends=('zlib' 'openmpi' 'bzip2')
- makedepends=('gcc-fortran' "cmake" "flex" "bison")
- provides=('ptscotch' 'ptscotch-openmpi' 'scotch_esmumps' 'scotch_ptesmumps')
- conflicts=('ptscotch-openmpi' 'scotch_esmumps' 'scotch_esmumps5')
- arch=('i686' 'x86_64')
- source=("https://gitlab.inria.fr/scotch/scotch/-/archive/v${pkgver}/${pkgname}-v${pkgver}.tar.gz")
- sha256sums=('8ef4719d6a3356e9c4ca7fefd7e2ac40deb69779a5c116f44da75d13b3d2c2c3')
- options=(!emptydirs)
- prepare() {
- [[ ! -d build ]] && mkdir build
- cd "${srcdir}/${pkgname}-v${pkgver}/src/"
- mkfile=${PWD}/Makefile.inc
- cp Make.inc/Makefile.inc.${CARCH/_/-}_pc_linux2.shlib ${mkfile}
- # Fix C compiler (still needed?)
- sed -i "s/CCD\t.*=.*gcc/CCD = mpicc/" ${mkfile}
- # Also enable bzip2 compression
- sed -i "s/-DCOMMON_FILE_COMPRESS_GZ/-DCOMMON_FILE_COMPRESS_GZ -DCOMMON_FILE_COMPRESS_BZ2/" ${mkfile}
- sed -i "s/-lz/-lz -lbz2/" ${mkfile}
- # Apply patch to fix shared library ldflags (still needed?)
- sed -i 's/$(AR) $(ARFLAGS) $(@) $(?)/$(AR) $(ARFLAGS) $(@) $(?) $(LDFLAGS)/g' \
- libscotch/Makefile
- }
- build() {
- cd "${srcdir}/${pkgname}-v${pkgver}"
- CONFOPTS=(
- -DCMAKE_INSTALL_PREFIX=/usr
- -DCMAKE_BUILD_TYPE=None
- -DCMAKE_COLOR_MAKEFILE=OFF
- -DCMAKE_CXX_COMPILER=mpicxx
- -DCMAKE_C_COMPILER=mpicc
- -DCMAKE_Fortran_COMPILER=mpifort
- -DCMAKE_C_FLAGS="${CFLAGS//-O2/-O3}"
- -DCMAKE_CXX_FLAGS="${CXXFLAGS//-O2/-O3}"
- -DINSTALL_METIS_HEADERS=OFF
- # -DINCLUDE_INSTALL_DIR=
- -DBUILD_LIBSCOTCHMETIS=ON
- -DBUILD_LIBESMUMPS=ON
- -DBUILD_PTSCOTCH=ON
- -DMPI_THREAD_MULTIPLE=ON
- -DTHREADS=ON
- -DINTSIZE:STRING="32"
- -DBUILD_SHARED_LIBS:BOOL=ON
- -DSCOTCH_PTHREAD:BOOL=ON
- -DSCOTCH_PTHREAD_MPI:BOOL=ON
- -DCOMMON_PTHREAD_AFFINITY_LINUX:BOOL=ON
- )
- echo CONFOPTS: ${CONFOPTS[@]}
- cmake -B "${srcdir}"/build -S "${srcdir}/${pkgname}-v${pkgver}" "${CONFOPTS[@]}"
- cmake --build "${srcdir}"/build
- }
- check() {
- cd "${srcdir}/${pkgname}-v${pkgver}/src"
- if [ -z $(ldconfig -p | grep libcuda.so.1) ]; then
- export OMPI_MCA_opal_warn_on_missing_libcuda=0
- fi
- ctest --test-dir "${srcdir}"/build
- }
- package() {
- cd "${srcdir}/${pkgname}-v${pkgver}/src"
- DESTDIR="${pkgdir}" cmake --build "${srcdir}"/build --target install
- # Gpart is no longer installed... why?
- # # To avoid conflict with extra/gpart, maybe move the package to /opt/scotch ?
- # mv "${pkgdir}/usr/bin/gpart" "${pkgdir}/usr/bin/gpart-scotch"
- mkdir -p "${pkgdir}"/usr/share/doc/"${pkgname}"
- cp -R ../doc/* "${pkgdir}"/usr/share/doc/"${pkgname}"
- install -m 644 -D "${pkgdir}"/usr/share/doc/scotch/CeCILL-C_V1-en.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
- }
|