castxml-pkgbuild/PKGBUILD

# Maintainer: Fabio 'Lolix' Loli <fabio.loli@disroot.org> -> https://github.com/FabioLolix

pkgname=castxml
pkgdesc="C-family abstract syntax tree XML output tool."
pkgver=0.4.8
pkgrel=1
arch=(i686 x86_64)
url="https://github.com/CastXML/CastXML"
license=(Apache)
depends=(llvm14 clang14)
makedepends=(cmake python-sphinx)
source=("$pkgname-$pkgver.tar.gz::https://github.com/CastXML/CastXML/archive/v$pkgver.tar.gz")
sha256sums=('0d62de13269076c2d36ad2feead8425447960d237cafab8c06f3e4dd2484d25c')

prepare() {
  cd "CastXML-$pkgver"

  # Fix build issue as reported by Kniyl here https://github.com/CastXML/CastXML/issues/102
  sed -i "s|\${llvm_libs}|LLVM|g" src/CMakeLists.txt

  CONFOPTS=(
    -DCMAKE_C_COMPILER=/usr/lib/llvm14/bin/clang
    -DCMAKE_CXX_COMPILER=/usr/lib/llvm14/bin/clang++
    -DCLANG_LINK_CLANG_DYLIB=1
    -DCLANG_RESOURCE_DIR=/usr/lib/llvm14/lib/clang/14.0.6/
    -DLLVM_DIR=/usr/lib/llvm14/lib/cmake/llvm/
    -DSPHINX_EXECUTABLE=/usr/bin/sphinx-build
    -DSPHINX_HTML=1
    -DSPHINX_MAN=1
    -DCMAKE_INSTALL_PREFIX=/usr
    -DCastXML_INSTALL_DOC_DIR=share/doc/castxml
    -DCastXML_INSTALL_MAN_DIR=share/man
  )
  cmake . ${CONFOPTS[@]}

}

build() {
  cd "CastXML-$pkgver"
  make
}

package(){
  cd "CastXML-$pkgver"
  make DESTDIR="$pkgdir" install
}