PKGBUILD 2.7 KB

1234567891011121314151617181920212223242526272829303132333435363738394041424344454647484950515253545556575859606162636465666768697071
  1. # Maintainer: Martin Diehl <aur@martin-diehl.net>
  2. # Contributor: eDgar <eDgar |at| openmail.cc >
  3. # Contributor: Michele Mocciola <mickele>
  4. # Contributor: Guillaume Dollé < dolle dot guillaume at gmail dot com >
  5. # Contributor: Lucas H. Gabrielli
  6. pkgname=mumps
  7. pkgver=5.3.5
  8. pkgrel=3
  9. pkgdesc='Sparse solver library using Gaussian elimination'
  10. url='http://mumps.enseeiht.fr'
  11. license=('custom')
  12. depends=('lapack' 'openmpi' 'scotch' 'scalapack' 'metis' 'zlib' 'bzip2')
  13. makedepends=('gcc-fortran')
  14. conflicts=('mumps-par' 'mumps4')
  15. arch=('i686' 'x86_64')
  16. source=(http://mumps.enseeiht.fr/MUMPS_${pkgver}.tar.gz
  17. Makefile.inc)
  18. sha512sums=('6e3bb081f38af8540ada7b4fb54c6e766739c854e2a3dd253e3e012eee05dae30064b1b4a8d7493f10691725aba4cc9e80544b0fe5b71670cb0b2726ccfc4439'
  19. '5064ca2b6101af1a3a92ca65fcbe20c1850bce24ad59dfecce66b195bbe9cd2f6e2637a5aaa7a0c0d000e7493a0ffe09f5523ad75d09a11b60292fa1e962f751')
  20. prepare () {
  21. cd "${srcdir}/MUMPS_${pkgver}"
  22. cp "${srcdir}/Makefile.inc" .
  23. }
  24. build() {
  25. cd "${srcdir}/MUMPS_${pkgver}"
  26. make alllib
  27. }
  28. check () {
  29. cd "${srcdir}/MUMPS_${pkgver}/examples"
  30. make all
  31. # From the README (in examples)
  32. MPIRUN="mpirun -np 3 --mca opal_warn_on_missing_libcuda 0 --oversubscribe"
  33. export LD_LIBRARY_PATH="${LD_LIBRARY_PATH}:${srcdir}/MUMPS_${pkgver}/lib"
  34. ${MPIRUN} ./ssimpletest < input_simpletest_real
  35. ${MPIRUN} ./dsimpletest < input_simpletest_real
  36. ${MPIRUN} ./csimpletest < input_simpletest_cmplx
  37. ${MPIRUN} ./zsimpletest < input_simpletest_cmplx
  38. ${MPIRUN} ./c_example
  39. ${MPIRUN} ./multiple_arithmetics_example
  40. ${MPIRUN} ./ssimpletest_save_restore < input_simpletest_real
  41. ${MPIRUN} ./dsimpletest_save_restore < input_simpletest_real
  42. ${MPIRUN} ./csimpletest_save_restore < input_simpletest_cmplx
  43. ${MPIRUN} ./zsimpletest_save_restore < input_simpletest_cmplx
  44. ${MPIRUN} ./c_example_save_restore
  45. }
  46. package(){
  47. # Install all headers
  48. cd "${srcdir}/MUMPS_${pkgver}/include"
  49. install -d -m755 "${pkgdir}/usr/include"
  50. install -D -m644 *.h "${pkgdir}/usr/include"
  51. # Install all libraries
  52. cd "${srcdir}/MUMPS_${pkgver}/lib"
  53. install -d -m755 ${pkgdir}/usr/lib
  54. install -D -m644 *.so ${pkgdir}/usr/lib
  55. # Install examples
  56. install -m 755 -d "${pkgdir}/usr/share/doc/${pkgname}/examples"
  57. cd "${srcdir}/MUMPS_${pkgver}/examples"
  58. install -m 644 * "${pkgdir}/usr/share/doc/${pkgname}/examples"
  59. install -m 644 "${srcdir}/MUMPS_${pkgver}/Makefile.inc" "${pkgdir}/usr/share/doc/${pkgname}/examples"
  60. sed -i 's_\(topdir =\).*_\1 /usr_g; s-.*\(Makefile.inc\)-include Makefile.inc-g' "${pkgdir}/usr/share/doc/${pkgname}/examples/Makefile"
  61. # Install license
  62. install -D -m644 "${srcdir}/MUMPS_${pkgver}/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
  63. }